Viele Benutzer anlegen

Im Folgenden wird gezeigt, wie man mit Batch-Dateien Benutzer ohne "Klicken" anlegen kann.

Anlegen eines einzelnen Schülers (SCHAN.BAT)

rem SCHAN.BAT - Batchdatei zum Anlegen eines Schuelers, Ausfuehrung am Server
rem AUFRUF: schan neuerSchueler Passwort Gruppe
rem Anlegen des Homeverzeichnisses
md F:\Home\%1
rem Der Schueler neuerSchueler wird angelegt.
net user %1 %2 /add /comment:"Schueler der Klasse %3"
rem Homeverzeichnisrechte werden vergeben
xcacls \\IKGServer\Home\%1 /G Administratoren:F Lehrer:C %1:C /y
rem Der Schueler wird der Klasse Gruppe hinzugefuegt
net group %3 %1 /add
net group schueler %1 /add
Aufruf: 
SCHAN K10A01 123456 K10A

Löschen eines einzelnen Schülers (SCHWEG.BAT)

rem SCHWEG.BAT - Batchdatei zum Loeschen eines Schuelers, Ausfuehrung am Server
rem AUFRUF: schweg Schueler
rem Loeschen des Homeverzeichnisses
rd /S /Q F:\Home\%1
rem Der Schueler Schueler wird geloescht.
net user %1 /DELETE
Aufruf: 
SCHWEG K10A01

Anlegen eines einzelnen Lehrers (LAN.BAT)

rem LAN.BAT Batchdatei zum Anlegen eines Lehrers, Ausfuehrung am Server
rem AUFRUF UEBER: LAN neuerLehrer Passwort
rem Anlegen des Homeverzeichnisses
md F:\Home\%1
rem Der Lehrer neuerLehrer wird angelegt.
net user %1 %2 /add /comment:"Lehrer"
rem Homeverzeichnisrechte werden vergeben
xcacls \\IKGServer\Home\%1 /G Administratoren:F %1:C /y
rem Der Lehrer wird der Gruppe Lehrer hinzugefuegt
net group Lehrer %1 /add
Aufruf: 
LAN L_Gierhardt 123456

Anlegen von vielen Schülern (XSCHAN.BAT)

Im aktuellen Verzeichnis (am besten D:\myprgs) muss die Textdatei SCHUELER.DAT liegen. Ein Beispiel für den Inhalt einer solchen Datei: 
K10A01,123456,K10A
K10A02,123656,K10A
K10A03,128756,K10A
K10A04,128576,K10A
K10A05,165756,K10A
K10B01,678456,K10B
K10B02,823456,K10B
K10B03,568345,K10B
K10B04,768546,K10B
K10B05,564789,K10B

Mit einer Excel-Datei Benutzer.xls (gezippt) kann man recht schnell eine solche Datei anlegen. Die richtige Spalte wird nur in eine neue Tabelle kopiert und im DOS-Text-Format abgespeichert. Bei jedem Laden der Excel-Datei werden dabei zufaellig neue Passwörter erzeugt.
Die Batchdatei: 
d:
cd \myprgs
FOR /F "tokens=1,2,3 delims=, " %%i IN (%1) DO net user %%i %%j /ADD /comment:"Schueler der Klasse %%k"
FOR /F "tokens=1 delims=, " %%i IN (%1) DO md F:\home\%%i
FOR /F "tokens=1 delims=, " %%i IN (%1) DO xcacls F:\home\%%i /G Administratoren:F Lehrer:C %%i:C /y
FOR /F "tokens=1,3 delims=, " %%i IN (%1) DO net group %%j %%i /ADD
FOR /F "tokens=1 delims=, " %%i IN (%1) DO net group schueler %%i /ADD
Aufruf: 
XSCHAN SCHUELER.DAT

Anlegen von vielen Lehrern (XLAN.BAT)

Im aktuellen Verzeichnis (am besten D:\myprgs) muss die Textdatei LEHRER.DAT liegen. Ein Beispiel für den Inhalt einer solchen Datei: 
L_Atorf-Fischer,UIQZT5
L_Aust,KLAT5E
Die Batchdatei: 
d:
cd \myprgs
FOR /F "tokens=1,2 delims=, " %%i IN (%1) DO net user %%i %%j /ADD /comment:"Lehrer"
FOR /F "tokens=1 delims=, " %%i IN (%1) DO md F:\home\%%i
FOR /F "tokens=1 delims=, " %%i IN (%1) DO xcacls F:\home\%%i /G Administratoren:F %%i:C /y
FOR /F "tokens=1 delims=, " %%i IN (%1) DO net group Lehrer %%i /ADD
Aufruf: 
XLAN LEHRER.DAT

Löschen von vielen Schülern (XSCHWEG.BAT)

Im aktuellen Verzeichnis (am besten D:\myprgs) muss die Textdatei LOESCH.DAT liegen (Inhalt wie in SCHUELER.DAT oder einfach nur aus Schülernamen bestehend). 
d:
cd \myprgs
FOR /F "tokens=1 delims=, " %%i IN (%1) DO rd /s /q F:\home\%%i
FOR /F "tokens=1 delims=, " %%i IN (%1) DO NET USER %%i /DELETE
Aufruf: 
XSCHWEG LOESCH.DAT
Alle Batchdateien gezippt.
batches2003.zip Die modifizierten Batchdateien, die 2003 benutzt wurden.

Weitere Einstellungen für Lehrer

Weitere Einstellungen für Schüler

- OK
Zurück zum Inhaltsverzeichnis